Using a logserver to handle this is a good idea on general principles. In your case, it might be easier to parse the dates, write the log entries in ISO format and sort them.

My logfiles are broken out by facility into kernlog, syslog, cronlog, etc. I appended all my logs from Dec 2025 into one file:

Dec  1 00:00:00 cron: (root) CMD (/usr/local/cron/ekg-driver)
Dec  1 00:00:00 cron: (root) CMD (/usr/local/cron/rlogcycle)
Dec  1 00:00:00 cron: (operator) CMD (/usr/libexec/save-entropy)
...
Dec 31 23:59:57 100.dmesg: saving dmesg
Dec 31 23:59:57 200.ets: converting dmesg

Here's a small perl script that parses the first three fields of each line into a usable date and writes it in ISO format. I'm sure you can do this in python or whatever floats your boat:

#!/usr/bin/perl
#<log2iso: read syslog files, format leading date as ISO time.

use Modern::Perl;
use Time::ParseDate;
use POSIX qw(strftime);

my $yr = '2025';

while (<>) {
    chomp;

    # Quick check -- look for 3-character month.
    next unless /^[A-Z][a-z][a-z] /;

    # First three fields are the date.
    my ($mo, $da, $hms, @arr) = split();
    my $date = "$mo $da $hms $yr";
    my $ms = '';
    my $rest = join(' ', @arr);

    # Allow epoch time with fractional seconds
    if (my $epoch = parsedate($date)) {
        $ms = $2 if ($hms =~ m/(\d+)(\.\d+)/);
        $date = strftime("%Y-%m-%d %T", localtime($epoch)) . "$ms";
        print "$date $rest\n";
    }
}

exit(0);

The script handled 300,000 lines in about 15 seconds. Results:

me% cat /var/log/2025/12*/* | log2iso | sort
2025-12-01 00:00:00 cron: (root) CMD (/usr/local/cron/ekg-driver)
2025-12-01 00:00:00 cron: (root) CMD (/usr/local/cron/rlogcycle)
2025-12-01 00:00:00 cron: (operator) CMD (/usr/libexec/save-entropy)
...
2025-12-31 23:59:57 100.dmesg: saving dmesg
2025-12-31 23:59:57 200.ets: converting dmesg

The script will handle dates with fractional seconds correctly.

HTH.